MS Excel untuk Pemetaan Tofografi

Memanfaatkan Program Microsoft Excel sebagai pengelola data dalam pembuatan peta tofografi, agar mempermudah dalam proses imput data dalam aplikasi Autocad, dan sejenisnya

EXCEL FOR MAPPING

Microsoft Excel atau Microsoft Office Excel adalah sebuah program aplikasi lembar kerja spreadsheet yang dibuat dan didistribusikan oleh Microsoft Corporation yang dapat dijalankan pada Microsoft Windows dan Mac OS.

Kali ini kita akan membahas kegunaan Aplikasi Microsoft Office Excel yang dipergunakan untuk pemetaan topografi.

Data Input

Data input yang diperoleh dari pemetaan topografi di lapangan adalah: 

a. Pembacaan benang atas,
b. Benang tengah,
c. Benang bawah,
d. Tinggi instrumen
e. Pembacaan sudut vertikal biasa dan luar biasa
f. Pembacaan azimuth biasa dan luar biasa
g. Titik ikat

Metode Penggunaan

Metode penggunaan  yang dimaksud disini adalah urutan pembuatan lembar kerja Excel dengan memadukan rumus perhitungan secara teoritis dengan fungsi-fungsi perhitungan program Excel. 

A. Membuat Tabel dan Memberi Judul 
Untuk membuat tabel kita harus memperhatikan jumlah data dan formula perhitungan. Untuk perhitungan data peta, banyaknya baris ditentukan oleh banyaknya data titik pengukuran. Sedangkan untuk banyaknya kolom ditentukan berdasarkan formula rumus untuk mengolah data. Lembar Kerja dibagi menjadi 3 sheet, terdiri dari sheet elevasi, sheet koordinat, sheet titik detil.

B. Memformat Kolom dan Baris Untuk Memudahkan Perhitungan

Memformat kolom dan baris bertujuan untuk memudahkan pembacaan dan alur perhitungan.

C. Memasukkan Data Pengukuran di Lapangan

Setelah format kolom dan baris terbentuk, data dari lapangan dapat segera dimasukkan. Data inilah yang menentukan banyaknya baris. Ketelitian dalam pengecekan data sangat diperlukan.

D. Membuat Formula Perhitungan

Pembuatan formula perhitungan dalam buku ini disusun berdasarkan format pembuatan peta topografi. Alur perhitungan dijelaskan dari kolom ke kolom pada masing-masing sheet pada file Perpetaan.

FORMAT PEMBUATAN PETA TOPOGRAFI TERDIRI DARI :
I) SHEET K_ELEVASI
Sheet ini berisi berisi sebagai berikut

1. Kolom B. Berisi informasi titik poligon dan data tinggi instrumen.
2. Kolom C.Merupakan informasi titik ikat poligon dari titik poligon kolom B.
3. Kolom D. Masukkan data perhitungan pembacaan Rambu Biasa benang atas (BA), benang tengah (BT), dan benang bawah (BB).
4. Kolom E. Masukkan data perhitungan pembacaan Rambu Luar Biasa benang atas (BA), benang tengah (BT), dan benang bawah (BB).
5. Kolom F, G, H. Masukkan data pembacaan Vertikal Biasa. Kolom F untuk angka derajat, Kolom G untuk angka menit, dan Kolom H untuk angka detik.
6. Kolom I. Kolom I berguna untuk merubah satuan Kolom F,G, dan H menjadi satuan derajat.
• Tempatkan pointer pada cell I10 kemudian masukkan rumus sebagai berikut :  =F10+G10/60+H10/3600
• Tempatkan pointer pada cell I11. I11 berguna untuk merubah data sudut pada cell I10 menjadi fungsi jarak. Masukkan rumus sebagai berikut :  =RADIANS(I10).
7. Kolom J,K,L. Masukkan data pembacaan Vertikal Luar Biasa. Kolom J untuk angka derajat, Kolom K untuk angka menit, dan Kolom L untuk angka detik. Tempatkan pointer pada cell J11. J11 berguna untuk merubah data sudut pada cell M10 menjadi fungsi jarak. Masukkan rumus sebagai berikut :  =RADIANS(M10).
8. Kolom M. berguna untuk merubah satuan Kolom J,K, dan L menjadi satuan derajat
• Tempatkan pointer pada cell M10 kemudian masukkan rumus sebagai berikut :  =J10+K10/60+L10/3600
• Tempatkan pointer pada cell M11. M11 berguna untuk merubah data sudut pada cell M10 menjadi fungsi jarak. Masukkan rumus sebagai berikut :  =RADIANS(M10).
9. Kolom N, O, P.
   Maukkan data pembacaan Azimuth Biasa. Kolom N untuk angka derajat, Kolom O untuk angka menit, dan Kolom P untuk angka detik.
10. Kolom Q. Kolom Q berguna untuk merubah satuan Kolom N,O, dan P menjadi satuan derajat. Tempatkan pointer pada cell Q10 kemudian masukkan rumus sebagai berikut :  =N10+O10/60+P10/3600.
11. Kolom R, S, T. Maukkan data pembacaan Azimuth Luar Biasa. Kolom R untuk angka derajat, Kolom S untuk angka menit, dan Kolom T untuk angka detik.
12. Kolom U. Kolom U berguna untuk merubah satuan Kolom R, S, dan T menjadi satuan derajat. Tempatkan pointer pada cell U10 kemudian masukkan rumus sebagai berikut :  =R10+S10/60+T10/3600.
13. Kolom V. Kolom ini merupakan kolom koreksi untuk pembacaan azimuth dari suatu titik n ke titik n+1 dan dari titik n+1 ke titik n. Contoh untuk koreksi titik I ke VII dan dari titik VII ke I. Tempatkan pointer pada cell V10 dan masukkan rumus sebagai berikut:

=IF(Q10>U10;(((Q10+U10+Q49+U49-360)/4)+180);(Q10+U10+Q49+U49-360)/4)



14. Kolom W. Kolom ini berguna untuk merubah hasil perhitungan Kolom V menjadi satuan derajat. Tempatkan pointer pada W10 dan masukkan rumus fungsi sebagai berkut : .

=ROUNDDOWN(V10;0)



15. Kolom X. Kegunaan Kolom X untuk merubah hasil perhitungan Kolom V menjadi satuan menit. Caranya tempatkan pointer ke cell X11 dulu, kemudian  masukkan rumus sebagai berikut : 

    =(V10-W10)*60

    Setelah itu tempatkan pointer pada cell X10 dan masukkan rumus berikut : 



=ROUNDDOWN(X11;0)



16. Kolom Y.Kegunaan Kolom X untuk merubah hasil perhitungan Kolom V menjadi satuan menit. Tempatkan pada cell Y10 dan masukkan rumusnya sebagai berikut : =(X11-X10)*60.
17. Kolom Z. Kolom Z merupakan kolom perhitungan jarak datar untuk pembacaan Biasa. Rumus teoritisnya : Dt = 100(BA-BB) Cos²f. Tempatkan pointer pada Z10 dan masukkan rumus perhitungan sebagai berikut : 

=100*(D9-D11)*COS(I11)*COS(I11)

atau


=100*(D9-D11)*COS(I11)^2



18. Kolom AA. Sama dengan formula Kolom Z, Kolom AA berguna untuk perhitungan jarak datar tetapi untuk pembacaan Luar Biasa. Tempatkan pointer pada AA10 dan masukkan rumus perhitungan sebagai berikut : 

=100*(E9-E11)*COS(J11)^2



19. Kolom AB. Kolom ini merupakan kolom koreksi jarak datar dari perhitungan dua titik pengamatan. Contoh untuk pengamatan dari titik I ke titik II . Tempatkan pointer pada cell AB13 dan masukkan rumus berikut :  

=(Z13+AA13+Z16+AA16)/4

Setelah semua titik dikoreksi, jumlahkan semua perhitungan pada kolom ini dengan menempatkan pointer di cell AB52 dan masukkan rumus berikut :


=SUM(AB10:AB51)

20. Kolom AC.Perhitungan beda tinggi dimulai dari kolom ini. Rumus teoritisnya adalah : Beda Tinggi (Dh = Dt. Tan f + (Ti-Bt). Untuk Pembacaan Biasa tempatkan pointer pada cell  AC10 dan masukkan rumus berikut: 

=Z10*TAN(I11)+(B11-D10)



21. Kolom AD. Untuk beda tinggi Pembacaan Luar Biasa tempatkan pointer pada cell  AD10 dan masukkan rumus berikut : 

=AA10*TAN(J11)+(B11-E10)



22. Kolom AE. Kolom ini adalah untuk menghitung koreksi beda tinggi di dua titik pengamatan. Tempatkan pointer pada Cell AE13 dan masukkan rumus formula sebagai berikut 

=IF(AC13<0;(((ABS(AC13))+(ABS(AD13))+(ABS(AC16))+(ABS(AD16)))/4*-1);((ABS(AC13))+(ABS(AD13))+(ABS(AC16))+(ABS(AD16))) /4)

Jumlahkan semua koreksi beda tinggi dengan rumus:umlahkan semua koreksi beda tinggi dengan rumus:


=SUM(AE10:AE51)



23. Kolom AF. Tinggi titik dihitung mulai kolom ini. Diperlukan data tinggi titik ikat. Tempatkan pointer pada cell AF10 dan ketik rumus berikut : =AF7-AE7.

=AF7-AE7



24. Kolom AG. Kolom AG untuk mengoreksi tinggi titik pada Kolom AF dengan memperhatikan koreksi beda tinggi pada Kolom AE. Tempatkan pointer pada AG10 dan masukkan rumus berikut :  

=AF10

Kemudian untuk tinggi titik poligon II tempatkan pointer di cell AG15 dan masukkan rumus berikut :


=AF15-((AB13/AB52)*AE52)

Untuk titik poligon III:


=AF21-((AB13+AB19)*AE52/AB52)

Untuk titik poligon IV:


=AF27-((AB13+AB19+AB25)*AE52/AB52)

Begitu seterusnya hingga pada poligon VII:


=AF47-((AB13+AB19+AB25+AB31+AB37+AB43)*AE52/AB52)

Untuk titik poligon semu I’ rumusnya :


=AF49-AE52



25. Kolom AH. Kolom ini membantu melihat titik pembentuk poligon.

II) SHEET K_KOORDINAT

Sheet ini berisi:

1. Kolom H, I, J. Tempatkan pointer mulai dari H7 sampai J7. Masukkan data koreksi azimut dari sheet K_ELEVASI  Kolom W13, X13, dan Y13. 
2. Kolom K. Kolom K berisi data yang sama dengan data pada sheet K_ELEVASI Kolom V. Tempatkan pointer pada cell K7 dan ketik :

= K_ELEVASI!V13

Begitu seterusnya hingga pada cell K19 dengan rumus:


=K_ELEVASI!V49



3. Kolom L. Kolom ini  untuk merubah data pada kolom K menjadi fungsi jarak. Sehingga rumus pada cell L7 :   

=RADIANS(K7)



4. Kolom M. Kolom ini berisi koreksi jarak datar yang sama dengan sheet K_ELEVASI kolom  AB. Tempatkan pointer pada M7 dan masukkan rumus berikut: 

=K_ELEVASI!AB13



5. Jumlahkan semua data kolom:

=SUM(M7:M20)



6. Kolom B. Kolom B merupakan kolom bantu untuk menghitung sudut dalam (b). Tempatkan pointer pada B6 dan masukkan rumus berikut:  

=(K19+180)-K7



7. Untuk  titik II, tempatkan pada B8 dan masukkan rumus: 

=(K7+180)-K9



8. Kolom C. Berisi informasi Titik Poligon.
9. Kolom D. Kolom D merupakan sudut dalam dengan satuan derajat dari hasil perhitungan kolom bantu dari data Kolom B. Tempatkan pointer pada D6. Rumusnya adalah:  

=ROUNDDOWN(B6;0)



10. Kolom G. Kolom ini membantu perhitungan sudut dalam untuk satuan menit dan detik pada kolom E dan F. Tempatkan pointer pada G6 masukkan rumus: 

=(B6-D6)*60



11. Kolom E. Merupakan kolom sudut dalam dengan satuan menit. Tempatkan pada E6 dan masukkan rumus: 

=ROUNDDOWN(G6;0)



12. Kolom F. Merupakan kolom sudut dalam dengan satuan detik. Tempatkan pada F6 dan masukkan rumus: 

=(G6-E6)*60



13. Kolom N. Kolom N merupakan perhitungan kesalahan linier jarak untuk absis. Rumus teoritis : f(x) = Dt.Sina. Sehingga formula pada cell N7 adalah  sebagai berikut : 

=M7*SIN(L7)

 Jumlahkan semua perhitungan pada N22.
14. Kolom O. Kolom O merupakan perhitungan kesalahan linier jarak untuk ordinat. Rumus teoritis : f(x) = Dt.CosSina. Sehingga formula pada cell N7 adalah  sebagai berikut : 

=M7*COS(L7)

 Jumlahkan semua perhitungan pada O22 
15. Kolom  P. Kolom P merupakan koreksi terhadap absis rumus torinya : kk_x= (Dt_n.f_x)/SDt. Sehingga formula perhitungan pada cell P7 menjadi  sebagai berikut : 

=$M7*$N$22*-1/$M$22



16. Kolom Q. Kolom P merupakan koreksi terhadap absis rumus torinya : k_y= (Dt_n.f_y)/SDt. Sehingga formula perhitungan pada cell Q7 menjadi  berikut : 

=$M7*$O$22*-1/$M$22



17. Kolom R. Pada kolom ini dilakukan koreksi terhadap nilai absis. Tempatkan pada cell R7 dengan formula: 

=N7+P7



18. Kolom S. Begitu pula pada kolom S ini dilakukan koreksi terhadap nilai ordinat. Tempatkan pada cell S7 dengan formula:  

=O7+Q7



19. Kolom T. Kolom ini berguna untuk menghitung Koordinat X. Caranya Tempatkan pointer pada T6 dan masukkan koordinat titik ikat X. Kemudian tempatkan pada T8 dan masukkan rumus berikut : 

=T6+R7



20. Kolom U. Kolom ini berguna untuk menghitung Koordinat Y. Caranya Tempatkan pointer pada U6 dan masukkan koordinat titik ikat Y. Kemudian tempatkan pada U8 dan masukkan rumus berikut : 

=U6+S7

21. Kolom  V. Berisi informasi bantu titik poligon, atau Keterangan.

MS Excel untuk Pemetaan Tofografi 2017-03-09T10:05:00+07:00 Rating: 4.5 Diposkan Oleh: Masyarakat Belajar